echo Welcome to "The Laffer Utilities" Version 4.01
space %1 6100 nospace
exists %2:Laffer.1  Insert Disk 1 in drive %2:
godir %1:\sierra\laffer CantCreate
echo
echo Installing Disk #1 of "The Laffer Utilities"
echo
echo %3 > resource.cfg
echo Copying a few files.
copy %2:\Inst*.*
copy %2:\EGA.drv
copy %2:\*.ptr
copy %2:\ReadMe.*
copy %2:\PrntLaff.bat
copy %2:\Laffer.cfg
copy %2:\__Laffer.bat %1:\Laffer.bat
copy %2:\__Laffer.bat  ..\Laffer.bat
copy %2:\pkUnZip.exe
echo
echo Decompressing background pictures...
pkUnZip -o %2:\pcx >NUL
cls

alert Insert Disk 2 in drive %2:
cls
exists %2:Laffer.2  Insert Disk 2 in drive %2:
echo Installing Disk #2 of "The Laffer Utilities"
echo
echo Copying the actual Laffer Utilities.
echo
copy %2:\*.exe

alert Insert Disk 3 in drive %2:
cls
exists %2:Laffer.3  Insert Disk 3 in drive %2:
echo Installing Disk #3 of "The Laffer Utilities"
echo
echo Decompressing lots and lots of jokes...
echo
pkUnZip -o %2:\db >NUL
echo Decompressing a ton of clip art...
pkUnZip -o %2:\cgm1 >NUL

alert Insert Disk 4 in drive %2:
cls
exists %2:Laffer.4  Insert Disk 4 in drive %2:
echo Installing Disk #4 of "The Laffer Utilities"
echo
echo Decompressing a few silly little sound effects.
pkUnZip -o %2:\snd >NUL
echo
echo Decompressing some really nifty business forms, 
echo fax cover sheets and faxable greeting cards you 
echo can fax on the company to all your frien... er, 
echo ah, customers!
echo
pkUnZip -o %2:\cgm2 >NUL
echo Decompressing a whole pantload of other stuff just 
echo to take up all that extra hard disk space you 
echo didn't know what to do with anyway!
pkUnZip -o %2:\misc >NUL

:SuccessfulConclusion
alert After carefully exploring your hard disk and noticing the quality of your work, I'd suggest you spend a little time polishing your resume!
end

:CantCreate
alert Unable to create directory %1:\Sierra\Laffer
exit
end

:nospace
clear
alert At least 6.1 megabytes of free disk space are necessary to install "The Laffer Utilities".  Clear off some of that unimportant old boring business software and try again, okay?
exit
end

:exit
end
